Socket 模块

CBrother提供了一个Socket扩展，它可以作为tcp服务器与客户端使用，也可以作为udp服务器与客户端使用。

TcpModule

TcpModule在windows下使用的是IOCP，在linux下使用的是epoll，在macOS下使用的是poll模型。

·TcpModule接口

setSocketAction,setThreadCount,setMaxConnectCount,setSockNormalBuflLen,addListenPort要在start之前调用。

·TcpModule 响应Action类可以有如下接口

function OnAccept(sock)，有新的连接。

function OnClose(sock)，连接断开。

function OnRecv(sock,byteArray,len)接收到数据。

function OnSend(sock,len)发送成功。

function OnConnect(sock)主动连接对端成功。

这个方法会被多线程调用，如果要访问公共资源需要加锁。但对于同一个socket而言,OnRecv是串行的。

·TcpModule 例子

服务器例子

import CBSocket.code
class TcpAction
{
    var tcpModule;
    function OnAccept(sock)
    {    
        print "accept " + sock;
    }
    function OnClose(sock)
    {
        print "onclose " + sock;
    }
    function OnRecv(sock,byteArray,len)
    {
        print "onrecv " + sock + " " + byteArray.readString() + " len:" + len;
        var byteArray = new ByteArray();
        byteArray.writeString("hello tcp client");
        tcpModule.sendData(sock,byteArray);
    }
    function OnSend(sock,len)
    {
        print "onsend " + sock + " " + len;
    }
}
function main(parm)
{
    var tcpModule = new TcpModule();
    var tcpAction = new TcpAction();
    tcpAction.tcpModule = tcpModule;
    tcpModule.setTcpAction(tcpAction);    //设置TCP处理类
    tcpModule.addListenPort(6060);    //监听6060端口
    tcpModule.addListenPort(6061,"*");    //监听6061端口,IPV4和IPV6兼容
    tcpModule.start();
    while(1)                //主线程不能退出
    {
        Sleep(1000);
    }
}

客户端例子

import CBSocket.code
class TcpAction
{
    var tcpModule;
    function OnClose(sock)
    {
        print "onclose " + sock;
    }
    function OnRecv(sock,byteArray,len)
    {
        print "onrecv " + sock + " " + byteArray.readString() + " len:" + len;
    }
    function OnSend(sock,len)
    {
        print "onsend " + sock + " " + len;
    }
    function OnConnect(sock)
    {
        print "onconnect " + sock;
        var byteArray = new ByteArray();
        byteArray.writeString("hellp tcp server!");
        tcpModule.sendData(sock,byteArray);
    }
}
function main(parm)
{
    var tcpModule = new TcpModule();
    var tcpAction = new TcpAction();
    tcpAction.tcpModule = tcpModule;
    tcpModule.setTcpAction(tcpAction);    //设置TCP处理类
    tcpModule.start();
    tcpModule.connect("127.0.0.1",6060);
    while(1)                //主线程不能退出
    {
        Sleep(1000);
    }
}

客户端结果如下：

onconnect 131072
onsend 131072 18
onrecv 131072 hello tcp client len:17

服务端结果如下：

accept 131072
onrecv 131072 hellp tcp server! len:18
onsend 131072 17

UdpModule

·UdpModule接口

setSocketAction,setThreadCount,setMaxConnectCount,setSockNormalBuflLen,addListenPort要在start之前调用。

·UdpModule 响应Action类可以有如下接口

function OnClose(sock)socket关闭

function OnRecv(sock,ip,port,byteArray,len)接收到数据。

这个方法会被多线程调用，如果要访问公共资源需要加锁。

·UdpModule 例子

服务器例子

import CBSocket.code
class UdpAction
{
    var udpModule;
    function OnClose(sock)
    {
        print "onclose " + sock;
    }
    function OnRecv(sock,ip,port,byteArray,len)
    {
        print "onrecv " + sock + " " + ip + " " + port + " " + byteArray.readString() + " len:" + len;
        var byteArray = new ByteArray();
        byteArray.writeString("hello udp client");    
        udpModule.sendData(sock,ip,port,byteArray);
    }
}
function main(parm)
{
    var udpModule = new UdpModule();
    var udpAction = new UdpAction();
    udpAction.udpModule = udpModule;
    udpModule.setUdpAction(udpAction);    //设置UDP处理类
    udpModule.start();
    udpModule.listen(6060);    //监听6060端口
    udpModule.listen(6061,"*");    //监听6061端口,IPV4和IPV6兼容    
    while(1)                //主线程不能退出
    {
        Sleep(1000);
    }
}

客户端例子

import CBSocket.code
class UdpAction
{
    var udpModule;
    function OnClose(sock)
    {
        print "onclose " + sock;
    }
    function OnRecv(sock,ip,port,byteArray,len)
    {        
        print "onrecv " + sock + " " + ip + " " + port + " " + byteArray.readString() + " len:" + len;
    }
}
function main(parm)
{
    var udpModule = new UdpModule();
    var udpAction = new UdpAction();
    udpAction.udpModule = udpModule;
    udpModule.setUdpAction(udpAction);    //设置TCP处理类
    udpModule.start();
    var byteArray = new ByteArray();
    byteArray.writeString("hello udp server");
    udpModule.connectSendTo("127.0.0.1",6060,byteArray);
    while(1)                //主线程不能退出
    {
        Sleep(1000);
    }
}

客户端结果如下：

onrecv 131072 127.0.0.1 6060 hello udp client len:17

服务端结果如下：

onrecv 131072 127.0.0.1 50332 hello udp server len:17