把数据存储到 XML 文件

通常，我们在数据库中存储数据。不过，如果希望数据的可移植性更强，我们可以把数据存储 XML 文件中。

创建并保存 XML 文件

如果数据要被传送到非 Windows 平台上的应用程序，那么把数据保存在 XML 文件中是有好处的。请记住，XML 有很强的跨平台可移植性，并且数据无需转换！

首先，我们将学习如何创建并保存一个 XML 文件。下面的这个 XML 文件将被命名为 "test.xml"，并被保存在服务器上的 c 目录中。我们将使用 ASP 和微软的 XMLDOM 对象来创建并保存这个 XML 文件：

  1. <%
  2. Dim xmlDoc, rootEl, child1, child2, p
  3.  
  4. '创建XML文档
  5. Set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")
  6.  
  7. '创建根元素并将之加入文档
  8. Set rootEl = xmlDoc.createElement("root")
  9. xmlDoc.appendChild rootEl
  10.  
  11. '创建并加入子元素
  12. Set child1 = xmlDoc.createElement("child1")
  13. Set child2 = xmlDoc.createElement("child2")
  14. rootEl.appendChild child1
  15. rootEl.appendChild child2
  16.  
  17. '创建 XML processing instruction
  18. '并把它加到根元素之前
  19. Set p=xmlDoc.createProcessingInstruction("xml","version='1.0'")
  20. xmlDoc.insertBefore p,xmlDoc.childNodes(0)
  21.  
  22. '把文件保存到 C 目录
  23. xmlDoc.Save "c:\test.xml"
  24. %>

如果您打开这个被保存的文件，它会使这个样子 ("test.xml")：

  1. <?xml version="1.0"?>
  2. <root>
  3.   <child1 />
  4.   <child2 />
  5. </root>

真实的表单例子

现在，我们看一个真实的表单例子。

我们首先看一下这个被用在例子中的 HTML 表单：下面的HTML表单要求用户输入他们的名字、国籍以及电子邮件地址。随后这些信息会被写到一个 XML 文件，以便存储。

"customers.htm":

  1. <html>
  2.  
  3. <body>
  4. <form action="saveForm.asp" method="post">
  5. <h1>请输入您的联系信息：</h1>
  6. <label>名字: </label>
  7. <p><input type="text" id="firstName" name="firstName"></p>
  8.  
  9. <label>姓氏: </label>
  10. <p><input type="text" id="lastName" name="lastName"></p>
  11.  
  12. <label>国家: </label>
  13. <p><input type="text" id="country" name="country"></p>
  14.  
  15. <label>邮件: </label>
  16. <p><input type="text" id="email" name="email"></p>
  17.  
  18. <p>
  19. <input type="submit" id="btn_sub" name="btn_sub" value="Submit">
  20. <input type="reset" id="btn_res" name="btn_res" value="Reset">
  21. </p>
  22. </form>
  23. </body>
  24.  
  25. </html>

用于以上 HTML 表单的 action 被设置为 "saveForm.asp"。"saveForm.asp" 文件是一个 ASP 页面，可循环遍表单域，并把它们的值存储在一个 XML 文件中：

  1. <%
  2. dim xmlDoc
  3. dim rootEl,fieldName,fieldValue,attID
  4. dim p,i
  5.  
  6. '如果有错误发生，不允许程序终止
  7. On Error Resume Next
  8.  
  9. Set xmlDoc = server.CreateObject("Microsoft.XMLDOM")
  10. xmlDoc.preserveWhiteSpace=true
  11.  
  12. '创建并向文档添加根元素
  13. Set rootEl = xmlDoc.createElement("customer")
  14. xmlDoc.appendChild rootEl
  15.  
  16. '循环遍历 Form 集
  17. for i = 1 To Request.Form.Count
  18.   '除去表单中的 button 元素
  19.   if instr(1,Request.Form.Key(i),"btn_")=0 then
  20.     '创建 field 和 value 元素，以及 id 属性
  21.     Set fieldName = xmlDoc.createElement("field")
  22.     Set fieldValue = xmlDoc.createElement("value")
  23.     Set attID = xmlDoc.createAttribute("id")
  24.     '把当前表单域的名称设置为 id 属性的值
  25.     attID.Text = Request.Form.Key(i)
  26.     '把 id 属性添加到 field 元素
  27.     fieldName.setAttributeNode attID
  28.     '把当前表单域的值设置为 value 元素的值
  29.     fieldValue.Text = Request.Form(i)
  30.     '将 field 元素作为根元素的子元素进行添加
  31.     rootEl.appendChild fieldName
  32.     '将 value 元素作为 field 元素的子元素进行添加
  33.     fieldName.appendChild fieldValue
  34.   end if
  35. next
  36.  
  37. '添加 XML processing instruction
  38. '并把它加到根元素之前
  39. Set p = xmlDoc.createProcessingInstruction("xml","version='1.0'")
  40. xmlDoc.insertBefore p,xmlDoc.childNodes(0)
  41.  
  42. '保存 XML 文件
  43. xmlDoc.save "c:\Customer.xml"
  44.  
  45. '释放所有的对象引用
  46. set xmlDoc=nothing
  47. set rootEl=nothing
  48. set fieldName=nothing
  49. set fieldValue=nothing
  50. set attID=nothing
  51. set p=nothing
  52.  
  53. '测试是否有错误发生
  54. if err.number<>0 then
  55.   response.write("Error: No information saved.")
  56. else
  57.   response.write("Your information has been saved.")
  58. end if
  59. %>

注释：如果指定的 XML 文件名已经存在，那个文件会被覆盖！

XML 文件会由上面的代码生成，大致的样子是这样的：("Customer.xml"):

  1. <?xml version="1.0" ?>
  2. <customer>
  3.   <field id="firstName">
  4.     <value>David</value> 
  5.   </field>
  6.   <field id="lastName">
  7.     <value>Smith</value> 
  8.   </field>
  9.   <field id="country">
  10.     <value>China</value> 
  11.   </field>
  12.   <field id="email">
  13.     <value>mymail@myaddress.com</value> 
  14.   </field>
  15. </customer>